100 PRINT CHR$(147):PRINT " SIDPLAYER SONG AND PICTURE DISSOLVER"
110 PRINT " BY CRAIG CHAMBERLAIN 2/1/87":PRINT:SP=783:DN=8
130 WR=3015:WU=WR+70:A=WU+77
135 L=PEEK(A):FOR K=1 TO L:F$=F$+CHR$(PEEK(A+K)):NEXT:A=A+K
140 ML=PEEK(A)+256*PEEK(A+1):MA=A+2:PA=MA+ML
300 PRINT " THIS PROGRAM WRITES TO DISK
305 [153] " THE MUSIC AND PICTURE FILES":[153] " FOR ONE SIDPLAYER SONG":[153]
320 [153] " INSERT A DISK TO RECEIVE":[153] " THE MUSIC AND PICTURE FILES,
325 PRINT " AND PRESS ANY KEY":PRINT
330 POKE 198,0:WAIT 198,15:GET G$
400 OPEN 2,DN,15:INPUT#2,A,B$,C,D:IF A GOTO 710
410 PRINT " WRITING " F$ ".MUS"
420 OPEN 1,DN,2,F$+".MUS,W,P":INPUT#2,A,B$,C,D:IF A GOTO 710
430 SYS WR,MA,MA+ML:IF PEEK(SP)AND1 GOTO 700
440 CLOSE 1:INPUT#2,A,B$,C,D:IF A GOTO 710
560 PRINT " WRITING " F$ ".PIC"
570 OPEN 1,DN,2,F$+".PIC,W,P":INPUT#2,A,B$,C,D:IF A GOTO 710
580 SYS WU,PA:IF PEEK(SP)AND1 GOTO 700
590 CLOSE 1:INPUT#2,A,B$,C,D:IF A GOTO 710
600 PRINT:PRINT " SCRATCH " F$ ".PIL? ";
610 WAIT 198,15:GET G$:IF G$="N" THEN PRINT "NO":GOTO 690
620 IF G$<>"Y" GOTO 610
630 PRINT "YES":PRINT#2,"S0:"+F$+".PIL":INPUT#2,A,B$,C,D:IF A>1 GOTO 710
690 CLOSE 2:END
700 INPUT#2,A,B$,C,D
710 PRINT:PRINT " ERROR: " B$:CLOSE 1:CLOSE 2:END